ASP メール処理


  目次



  メール送信用オブジェクト CDO for Windows 2000 について




以下は Microsoft の説明の一部を翻訳したものです

CDO for Windows 2000は、Microsoft ActiveXを必要とします。 このコンポーネントは、オペレーティングシステムのWindows2000シリーズの不可欠の部分であり、したがって、インストールする必要はありません。
当然 Windows XP でも動作します

ASP で使用する為の タイプライブラリの定数利用のサンプルコードを以下に示します

TyplibTest.asp
  

<!--METADATA
	TYPE="typelib"
	UUID="CD000000-8B95-11D1-82DB-00C04FB1625D"
	NAME="CDO for Windows 2000 Type Library" -->

<H4>CDO for Windows 2000 定数 (抜粋)</H4>
<TABLE>
<TR>
	<TD><b>cdoTo</b></TD>
	<TD><%= cdoTo %></TD>
</TR>
<TR>
	<TD><b>cdoFrom</b></TD>
	<TD><%= cdoFrom %></TD>
</TR>
<TR>
	<TD><b>cdoUTF_8</b></TD>
	<TD><%= cdoUTF_8 %></TD>
</TR>
<TR>
	<TD><b>cdoSendUsingPickup</b></TD>
	<TD><%= cdoSendUsingPickup %></TD>
</TR>
<TR>
	<TD><b>cdoSendUsingPort</b></TD>
	<TD><%= cdoSendUsingPort %></TD>
</TR>
</TABLE>
  

CDO for Windows 2000 定数 (抜粋)

cdoTo urn:schemas:httpmail:to
cdoFrom urn:schemas:httpmail:from
cdoUTF_8 utf-8
cdoSendUsingPickup 1
cdoSendUsingPort 2

  メール送信

以下は、テキストメールの送信です

  

<%
Call Response.AddHeader( "Content-Type", "text/html; Charset=shift_jis" )
Response.ExpiresAbsolute=#May 31,2000 23:59:59#

Dim strMessage

' **********************************************************
' MODEL
' **********************************************************
function SendMail()

	if Trim( Request.Form( "Body" ) ) = "" then
		strMessage = "本文を入力して下さい"
	end if
	if Trim( Request.Form( "From" ) ) = "" then
		strMessage = "送信者を入力して下さい"
	end if
	if Trim( Request.Form( "Subject" ) ) = "" then
		strMessage = "件名を入力して下さい"
	end if
	if Trim( Request.Form( "To" ) ) = "" then
		strMessage = "宛先を入力して下さい"
	end if
	if strMessage <> "" then
		Exit Function
	end if

	Set Cdo = Server.CreateObject("CDO.Message")

	Cdo.From = Request.Form( "From" )
	Cdo.To = Request.Form( "To" )
	Cdo.Subject	= Request.Form( "Subject" )
	Cdo.Textbody	= Request.Form( "Body" )

	Cdo.Configuration.Fields.Item _
	 ("http://schemas.microsoft.com/cdo/configuration/sendusing") = _
		2
	Cdo.Configuration.Fields.Item _
	 ("http://schemas.microsoft.com/cdo/configuration/smtpserver") = _
		"SMTPサーバのアドレス"
	Cdo.Configuration.Fields.Item _
	 ("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = _
		25
	Cdo.Configuration.Fields.Update

	on error resume next
	Cdo.Send
	if Err.Number <> 0 then
		strMessage = Err.Description
	else
		strMessage = "送信が完了しました"
	end if
	on error goto 0

end function

' **********************************************************
' CONTROL
' **********************************************************
	if Request.Form( "send" ) = "送信" then
		Call SendMail()
	end if

%>

<!-- **********************************************************
  VIEW
*********************************************************** -->
<FORM method=POST>
宛先 <INPUT type=text name=To size=100
 value="<%= Request.Form( "To" ) %>"><br>
件名 <INPUT type=text name=Subject size=100
 value="<%= Request.Form( "Subject" ) %>"><br>
送信者 <INPUT type=text name=From size=100
 value="<%= Request.Form( "From" ) %>"><br>
<br>
<TEXTAREA
	cols=80
	rows=20
	name=Body
><%= Request.Form( "Body" ) %></TEXTAREA>
<INPUT type=submit name=send value="送信">
</FORM>
<HR>
<%= strMessage %>
  

  

HTML メールは Cdo.Htmlbody を使用します
( "<PRE>" & Request.Form( "Body" ) & "</PRE>" をセットすると良いでしょう )

添付ファイルは Cdo.AddAttachment( "添付ファイルへのパス" ) を実行します
  

詳細は Microsoft の こちら を参照して下さい

↓configuration フィールドの詳細
http://msdn.microsoft.com/en-us/library/ms526318(EXCHG.10).aspx

↓送信時のユーザー・パスワードの設定
http://winofsql.jp/VA003334/webwsh070428231841.htm

テキストエリアで タブを入力したい場合は こちら

  SMTP 認証に関して

clear text のみですが、以下のように指定します

  

	' Authentication Enum for smtpauthenticate
	' cdoAnonymous 0  Perform no authentication.
	' cdoBasic 1  Use the basic (clear text) authentication mechanism.
	' cdoNTLM 2 Use the NTLM authentication mechanism.

	Cdo.Configuration.Fields.Item _
	 ("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
	Cdo.Configuration.Fields.Item _
	 ("http://schemas.microsoft.com/cdo/configuration/sendusername") = MailUser
	Cdo.Configuration.Fields.Item _ 
	 ("http://schemas.microsoft.com/cdo/configuration/sendpassword") = MailPass
  




yahoo  google  MSDN  MSDN(us)  WinFAQ  Win Howto  tohoho  ie_DHTML  vector  wdic  辞書  天気 


[asp]
CCBot/2.0 (https://commoncrawl.org/faq/)
19/06/25 17:11:47
InfoBoard Version 1.00 : Language=Perl

BatchHelper COMprog CommonSpec Cprog CprogBase CprogSAMPLE CprogSTD CprogSTD2 CprogWinsock Cygwin GameScript HTML HTMLcss InstallShield InstallShieldFunc JScript JScriptSAMPLE Jsfuncs LLINK OldProg OracleGold OracleSilver PRO PRObrowser PROc PROconePOINT PROcontrol PROftpclient PROjscript PROmailer PROperl PROperlCHAT PROphp PROphpLesson PROphpLesson2 PROphpLesson3 PROphpfunction PROphpfunctionArray PROphpfunctionMisc PROphpfunctionString PROsql PROvb PROvbFunction PROvbString PROvbdbmtn PROvbonepoint PROwebapp PROwin1POINT PROwinSYSTEM PROwinYOROZU PROwindows ProjectBoard RealPHP ScriptAPP ScriptMaster VBRealtime Vsfuncs a1root access accreq adsi ajax amazon argus asp aspSample aspVarious aspdotnet aw2kinst cappvariety centura ckeyword classStyle cmaterial cmbin cmdbapp cmenum cmlang cmlistbox cmstd cmstdseed cmtxt cs daz3d db dbCommon dbaccess dnettool dos download flex2 flex3 flex4 framemtn framereq freeWorld freesoft gimp ginpro giodownload google hdml home hta htmlDom ie9svg install java javaSwing javascript jetsql jquery jsp jspTest jspVarious lightbox listasp listmsapi listmsie listmsiis listmsnt listmspatch listmsscript listmsvb listmsvc memo ms msde mysql netbeans oraPlsql oracle oracleWiper oraclehelper orafunc other panoramio pear perl personal pgdojo pgdojo_cal pgdojo_holiday pgdojo_idx pgdojo_ref pgdojo_req php phpVarious phpguide plsql postgres ps r205 realC realwebapp regex rgaki ruby rule sboard sc scprint scquest sdb sdbquest seesaa setup sh_Imagick sh_canvas sh_dotnet sh_google sh_tool sh_web shadowbox shgm shjquery shvbs shweb sjscript skadai skywalker smalltech sperl sqlq src systemdoc tcpip tegaki three toolbox twitter typeface usb useXML vb vbdb vbsfunc vbsguide vbsrc vpc wcsignup webanymind webappgen webclass webparts webtool webwsh win8 winofsql wmi work wp youtube