VBScript : デスクトップに Google Chrome を使用したドキュメント( HTML ) のショートカットを作成する


  スクリプトのダウンロードと概要





ブラウザでダウンロード

自分にとって、各ブラウザは目的にあわせて使うツールなのですが、Google Chrome は現在ローカルファイルのドキュメントの参照に使っています。

しかし、どうや Chrome5 になってから、引数に --allow-file-access-from-files を指定しないと フレームの target が正しく動かないようなので、面倒なので登録用のスクリフトを作成しました。

実行すると、ファイルを選択するのダイアログが表示されるので、目的の index.html 等を選択すると、一つ上の階層のディレクトリ名で、デスクトップにショートカットを作成します。

※ アイコンは、Google Chrome の 3 番目のアイコンを使用しています
Flex3_doc_chrome_icon

※ HOT キーは、CTRL+CHIFT+G で決め打ちなので変更して利用して下さい

以下は Flex3 のドキュメントを Google Chrome で開いたところです

Flex3_doc_chrome


関連する記事

Google Chrome 公式ヘルプフォーラム
targetを設定していても新しいタブを開いてしまうのですが使えなくなったのですか?

  ソースコード




ショートカット作成で最も解りにくいのは引数の設定です。
Microsoft のオンラインドキュメントでは、サンプルに Arguments の記載が無い上に該当ページには、WSH の Arguments プロパティ の説明しかありません。

Chrome の場所 は、レジトリ内のアンインストールのエントリより取得しています。
確実ではないかもしれないので、その場合は直接スクリプトの該当部分を書きなおして使って下さい
strTarget が、Chrome.exe へのパスです( Chromium を使用するのであればそうする必要があります )

※ 普通に引数部分を記述して下さい

Microsoft の関連ページ

CreateShortcut メソッド
WshShortcut オブジェクト

<JOB>
<COMMENT>
************************************************************
■デスクトップにChrome で ドキュメント( HTML )の
 ショートカットを作成する

■著作権その他

このプログラムはフリーです。どうぞ自由に御使用ください。
著作権は作者である私(lightbox)が保有しています。
また、本ソフトを運用した結果については、作者は一切責任を
負えせんのでご了承ください。
************************************************************
</COMMENT>

<OBJECT id="WshShell" progid="WScript.Shell" />
<OBJECT id="Fso" progid="Scripting.FileSystemObject" />
<OBJECT id="Shell" progid="Shell.Application" />

<COMMENT>
************************************************************
* lightbox WEB WSH コアライブラリ
************************************************************
</COMMENT>
<SCRIPT language="VBScript" src="http://homepage2.nifty.com/lightbox/laylaClass.vbs"></SCRIPT>

<COMMENT>
************************************************************
* スクリプト開始
************************************************************
</COMMENT>
<SCRIPT language=VBScript>
' OpenFileName3 を実行する為のライブラリ設定
Call laylaFunctionTarget( "http://homepage2.nifty.com/lightbox/" )
Call laylaLoadFunction( "baseFunction.vbs" )
Call laylaLoadFunction( "toolFunction.vbs" )

Const SHORTCUT_WindowStyle_Default = 1
Const SHORTCUT_WindowStyle_Maximized = 3
Const SHORTCUT_WindowStyle_Minimized = 7

' ***********************************************************
' 処理開始
' ***********************************************************
' GUI 
if vbCancel = MsgBox( "処理を開始しますか?   ", vbOKCancel , _
	"Desktop to Chrome Shortcut for Flex3 document" ) then
	Wscript.Echo "キャンセルされました"
	Wscript.Quit
end if

' スクリプトが存在するディレクトリ
strCurPath = WScript.ScriptFullName
Set obj = Fso.GetFile( strCurPath )
Set obj = obj.ParentFolder
strCurPath = obj.Path

' Chrome の場所
strKey = "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Uninstall\Google Chrome"
strTarget = WshShell.RegRead(strKey & "\DisplayIcon")

' デスクトップのパス
strDesktop = WshShell.SpecialFolders("Desktop")

' 対象 HTML の選択
TargetHTML = OpenFileName3()
if TargetHTML(0) <> "" then

	' ショートカットのパス
	strWorkPath = TargetHTML(0)
	Set obj = Fso.GetFile( strWorkPath )
	Set obj = obj.ParentFolder
	' 対象ファイルの一つ上のディレクトリ名を使用する
	set obj = WshShell.CreateShortcut( strDesktop & "\" & obj.Name & ".lnk")

	obj.TargetPath = strTarget
	obj.Arguments = "--allow-file-access-from-files """ & TargetHTML(0) & """"
	obj.WindowStyle = SHORTCUT_WindowStyle_Default
	obj.Hotkey = "CTRL+SHIFT+G"
	obj.IconLocation = strTarget & ", 2"
	obj.Description = "Flex3のドキュメントのショートカット"
	obj.WorkingDirectory = strCurPath & "\langref"
	obj.Save

	Wscript.Echo "処理が終了しました"
else
	Wscript.Echo "HTML を選択しませんでした"
end if

</SCRIPT>
</JOB>





yahoo  google  MSDN  MSDN(us)  WinFAQ  Win Howto  tohoho  ie_DHTML  vector  wdic  辞書  天気 


[sh_tool]
claudebot
24/03/29 10:56:38
InfoBoard Version 1.00 : Language=Perl

1 BatchHelper COMprog CommonSpec Cprog CprogBase CprogSAMPLE CprogSTD CprogSTD2 CprogWinsock Cygwin GameScript HTML HTMLcss InstallShield InstallShieldFunc JScript JScriptSAMPLE Jsfuncs LLINK OldProg OracleGold OracleSilver PRO PRObrowser PROc PROconePOINT PROcontrol PROftpclient PROjscript PROmailer PROperl PROperlCHAT PROphp PROphpLesson PROphpLesson2 PROphpLesson3 PROphpfunction PROphpfunctionArray PROphpfunctionMisc PROphpfunctionString PROsql PROvb PROvbFunction PROvbString PROvbdbmtn PROvbonepoint PROwebapp PROwin1POINT PROwinSYSTEM PROwinYOROZU PROwindows ProjectBoard RealPHP ScriptAPP ScriptMaster VBRealtime Vsfuncs a1root access accreq adsi ajax amazon argus asp aspSample aspVarious aspdotnet aw2kinst cappvariety centura ckeyword classStyle cmaterial cmbin cmdbapp cmenum cmlang cmlistbox cmstd cmstdseed cmtxt cs daz3d db dbCommon dbaccess dnettool dos download flex2 flex3 flex4 framemtn framereq freeWorld freesoft gimp ginpro giodownload google hdml home hta htmlDom ie9svg install java javaSwing javascript jetsql jquery jsp jspTest jspVarious lightbox listasp listmsapi listmsie listmsiis listmsnt listmspatch listmsscript listmsvb listmsvc memo ms msde mysql netbeans oraPlsql oracle oracleWiper oraclehelper orafunc other panoramio pear perl personal pgdojo pgdojo_cal pgdojo_holiday pgdojo_idx pgdojo_ref pgdojo_req php phpVarious phpguide plsql postgres ps r205 realC realwebapp regex rgaki ruby rule sboard sc scprint scquest sdb sdbquest seesaa setup sh_Imagick sh_canvas sh_dotnet sh_google sh_tool sh_web shadowbox shgm shjquery shvbs shweb sjscript skadai skywalker smalltech sperl sqlq src systemdoc tcpip tegaki three toolbox twitter typeface usb useXML vb vbdb vbsfunc vbsguide vbsrc vpc wcsignup webanymind webappgen webclass webparts webtool webwsh win8 winofsql wmi work wp youtube