ファイル選択ダイアログを開く


  InternetExplorer.Application の利用




スクリプトからファイル選択ダイアログを開く方法は、XP を除く OS では正式に用意されていません。ですから、完全なコントロールはできませんが、InternetExplorer.Application を使用するとなんとか使う事ができます
( 但し Cscript.exe からは実行できません )

' 管理者として実行を強制する
Set obj = Wscript.CreateObject("Shell.Application")
if Wscript.Arguments.Count = 0 then
	obj.ShellExecute "wscript.exe", WScript.ScriptFullName & " runas", "", "runas", 1
	Wscript.Quit
end if

' ファイルシステムを操作するオブジェクト
Set Fso = WScript.CreateObject( "Scripting.FileSystemObject" )
' テンポラリフォルダ
TempDir =  Fso.GetSpecialFolder(2)
on error resume next
' テンポラリフォルダに空の "local.htm" を作成
Set objHandle = Fso.CreateTextFile( TempDir & "\local.htm", True, True )
if Err.Number <> 0 then
	Wscript.Quit
end if
objHandle.Close
on error goto 0

' IE を操作するオブジェクト
Set IEDocument = WScript.CreateObject( "InternetExplorer.Application" )
' テンポラリフォルダに作成したファイルを開く
IEDocument.Navigate( TempDir & "\local.htm" )
' 『ファイルを開く』為のコンテンツを作成
IEDocument.document.getElementsByTagName("BODY")(0).innerHTML = "<input id=FilePath type=file>"
' 『ファイルを開く』為に、ボタンをクリックする
IEDocument.document.getElementById("FilePath").click
' ファイルを選択していない場合は終了
if IEDocument.document.getElementById("FilePath").value = "" then
	OpenLocalFileName = ""
	IEDocument.Quit
	Set IEDocument = Nothing
	Wscript.Quit
end if

' 選択したファイルのパスを戻す
Wscript.Echo IEDocument.document.getElementById("FilePath").value

' IE を終了
IEDocument.Quit
Set IEDocument = Nothing












  UserAccounts.CommonDialog




Windows XP は以下のようにして実現できます

  

Set objDialog = CreateObject("UserAccounts.CommonDialog")

objDialog.Filter = "全て|*.*|テキスト|*.txt"
objDialog.InitialDir = "C:\"
nRet = objDialog.ShowOpen
 
if nRet = 0 then
	Wscript.Quit
End If

WScript.Echo objDialog.FileName
  

Microsoft へのリンク




yahoo  google  MSDN  MSDN(us)  WinFAQ  Win Howto  tohoho  ie_DHTML  vector  wdic  辞書  天気 


[vbsguide]
CCBot/2.0 (https://commoncrawl.org/faq/)
19/06/25 16:32:28
InfoBoard Version 1.00 : Language=Perl

BatchHelper COMprog CommonSpec Cprog CprogBase CprogSAMPLE CprogSTD CprogSTD2 CprogWinsock Cygwin GameScript HTML HTMLcss InstallShield InstallShieldFunc JScript JScriptSAMPLE Jsfuncs LLINK OldProg OracleGold OracleSilver PRO PRObrowser PROc PROconePOINT PROcontrol PROftpclient PROjscript PROmailer PROperl PROperlCHAT PROphp PROphpLesson PROphpLesson2 PROphpLesson3 PROphpfunction PROphpfunctionArray PROphpfunctionMisc PROphpfunctionString PROsql PROvb PROvbFunction PROvbString PROvbdbmtn PROvbonepoint PROwebapp PROwin1POINT PROwinSYSTEM PROwinYOROZU PROwindows ProjectBoard RealPHP ScriptAPP ScriptMaster VBRealtime Vsfuncs a1root access accreq adsi ajax amazon argus asp aspSample aspVarious aspdotnet aw2kinst cappvariety centura ckeyword classStyle cmaterial cmbin cmdbapp cmenum cmlang cmlistbox cmstd cmstdseed cmtxt cs daz3d db dbCommon dbaccess dnettool dos download flex2 flex3 flex4 framemtn framereq freeWorld freesoft gimp ginpro giodownload google hdml home hta htmlDom ie9svg install java javaSwing javascript jetsql jquery jsp jspTest jspVarious lightbox listasp listmsapi listmsie listmsiis listmsnt listmspatch listmsscript listmsvb listmsvc memo ms msde mysql netbeans oraPlsql oracle oracleWiper oraclehelper orafunc other panoramio pear perl personal pgdojo pgdojo_cal pgdojo_holiday pgdojo_idx pgdojo_ref pgdojo_req php phpVarious phpguide plsql postgres ps r205 realC realwebapp regex rgaki ruby rule sboard sc scprint scquest sdb sdbquest seesaa setup sh_Imagick sh_canvas sh_dotnet sh_google sh_tool sh_web shadowbox shgm shjquery shvbs shweb sjscript skadai skywalker smalltech sperl sqlq src systemdoc tcpip tegaki three toolbox twitter typeface usb useXML vb vbdb vbsfunc vbsguide vbsrc vpc wcsignup webanymind webappgen webclass webparts webtool webwsh win8 winofsql wmi work wp youtube