Lightbox Info Board : SQLの窓

バイナリファイルを除くファイルの操作や、ディレクトリ関連の操作を行なうオブジェクトです
以下にタイプライブラリに定義している定数の一覧 ( C++ の表現 ) を示します


enum CompareMethod
{
    BinaryCompare = 0,
    TextCompare = 1,
    DatabaseCompare = 2
};

enum IOMode
{
    ForReading = 1,
    ForWriting = 2,
    ForAppending = 8
};

enum Tristate
{
    TristateTrue = -1,
    TristateFalse = 0,
    TristateUseDefault = -2,
    TristateMixed = -2
};
enum __MIDL___MIDL_itf_scrrun_0000_0001
{
    Normal = 0,
    ReadOnly = 1,
    Hidden = 2,
    System = 4,
    Volume = 8,
    Directory = 16,
    Archive = 32,
    Alias = 1024,
    Compressed = 2048
};
enum __MIDL___MIDL_itf_scrrun_0094_0001
{
    UnknownType = 0,
    Removable = 1,
    Fixed = 2,
    Remote = 3,
    CDRom = 4,
    RamDisk = 5
};
enum __MIDL___MIDL_itf_scrrun_0094_0002
{
    WindowsFolder = 0,
    SystemFolder = 1,
    TemporaryFolder = 2
};
enum __MIDL___MIDL_itf_scrrun_0094_0003
{
    StdIn = 0,
    StdOut = 1,
    StdErr = 2
};

fs.inc


<SCRIPT language=VBScript RUNAT=server>

Dim FileSystem

' ******************************************************
' 初期化
' ******************************************************
Function FsInit()

	If Not IsObject(FileSystem) Then
		Set FileSystem = CreateObject("Scripting.FileSystemObject")
	End If

End Function

' ******************************************************
' ファイルの読み込みオープン
' ******************************************************
Function FsReadOpen(strFileName)

	Call FsInit

	Set FsReadOpen = FileSystem.OpenTextFile( _
		strFileName, _
		Scripting.ForReading _
	)

End Function

' ******************************************************
' ファイルの書き込み(作成・上書き)オープン
' ******************************************************
Function FsWriteOpen(strFileName)

	Call FsInit

	Set FsWriteOpen = FileSystem.CreateTextFile( _
		strFileName, _
		True _
	)

End Function

' ******************************************************
' クローズ
' ******************************************************
Function FsClose(fp)

	Call fp.Close()
	Set fp = Nothing

End Function

' ******************************************************
' EOF
' ******************************************************
Function FsEof(fp)

	FsEof = fp.AtEndOfStream

End Function

' ******************************************************
' ファイルの複写( 上書き )
' ******************************************************
Function FsCopy(strFrom, strTo)

	Call FsInit

	FileSystem.CopyFile strFrom, strTo, True

End Function

' ******************************************************
' テンポラリディレクトリの取得
' ******************************************************
Function FsGetTmp()

	Call FsInit

	FsGetTmp = FileSystem.GetSpecialFolder( _
		Scripting.TemporaryFolder _
	)

End Function

' ******************************************************
' 存在チェック
' ******************************************************
Function FsIsFileExist(Spec)

	Call FsInit

	FsIsFileExist = FileSystem.FileExists(Spec)

End Function
Function FsIsDirExist(Spec)

	Call FsInit

	FsIsDirExist = FileSystem.FolderExists(Spec)

End Function
Function FsIsDriveExist(Spec)

	Call FsInit

	FsIsDriveExist = FileSystem.DriveExists(Spec)

End Function

' ******************************************************
' カレントディレクトリ取得
' ******************************************************
Function FsGetCurDir()

	Call FsInit

	FsGetCurDir = FileSystem.GetAbsolutePathName(".")

End Function

' ******************************************************
' ファイルの削除
' ******************************************************
Function FsDeleteFile(TargetFile)

	Call FsInit

	Call FileSystem.DeleteFile(TargetFile, True)

End Function

</SCRIPT>

frame.htm


<HTML>
<HEAD>
<TITLE>テキストファイル</TITLE>
<META HTTP-EQUIV="Content-Type" CONTENT="text/html; CHARSET=shift_jis">
</HEAD>
<FRAMESET id="TopFrame" rows="200,*">
	<FRAME name="HeadFrame" src="control.asp?view=head">
	<FRAME name="BodyFrame" src="control.asp?view=body">
</FRAMESET>
</HTML>

control.asp


<%
' **********************************************************
' 外部ファイル
' **********************************************************
%><!-- #include virtual = "/asp/common.inc" --><%
%><!-- #include virtual = "/asp/dbMySQL.inc" --><%
%><!-- #include virtual = "/asp/fs.inc" --><%
%><!-- #include file = "model.inc" --><%

' **********************************************************
' 定数定義
' **********************************************************
Const PASS_MESSAGE = "1"
Const PASS_COND = "2"
Const PASS_LIST = "3"

' **********************************************************
' グローバル変数定義
' **********************************************************
Dim ErrMessage		' エラー処理用
Dim Message			' 通常メッセージ用
Dim InData			' フレーム間引継ぎ埋め込み用
Dim OptionList		' コンボボックス埋め込み用
Dim OutData			' 結果表示埋め込み用
Dim Cn,Rs			' データベース用

' ------------------------------------------------
' データベース接続
' ------------------------------------------------
Call DBConnectByEnv( Cn )

' **********************************************************
' 処理コントロール
' **********************************************************
Select Case Request.ServerVariables( "REQUEST_METHOD" )
	Case "GET","POST"
		Select Case MyData("GNO")
			Case PASS_COND
				if MyData("send") = "書き込み" then
					Call WriteData( )
				end if
				if MyData("send") = "読み込み" then
					Call ReadData( )
				end if
				if ErrMessage <> "" then
					MyData("GNO") = PASS_MESSAGE
				end if
			Case PASS_LIST
				Call GetData( )
		End Select
End Select

' **********************************************************
' ビュー
' **********************************************************
CreateInData( )
Select Case MyData("GNO")
	Case PASS_MESSAGE
		%><!-- #include file = "viewmessage.inc" --><%

	Case PASS_COND
		Call EditDataBody()
		%><!-- #include file = "view2.inc" --><%

	Case PASS_LIST
		Call EditDataBody()
		%><!-- #include file = "view2.inc" --><%

	Case Else
		if MyData("view") = "head" then
			Call RestoreCookie( )
			Call EditDataHead( )
			%><!-- #include file = "view.inc" --><%
		end if
		if MyData("view") = "body" then
			%><!-- #include file = "viewmessage.inc" --><%
		end if

End Select

' ------------------------------------------------
' データベース接続解除
' ------------------------------------------------
Call DBClose( Cn )
Call DBClose( Rs )

' **********************************************************
' デバッグ用
' **********************************************************
DispData()

%>

model.inc


<%
' **********************************************************
' データ読出し
' **********************************************************
Function GetData( )


End Function

' **********************************************************
' 書き込み
' **********************************************************
Function WriteData( )

	Dim fp

	OutData = Replace( MyData("In1Text"), vbCrLf, "<br>" )

	Set fp = FsWriteOpen( Server.MapPath("Data.txt") )
	Call fp.WriteLine( MyData("In1Text") )
	Call FsClose( fp )

End Function

' **********************************************************
' 読み込み
' **********************************************************
Function ReadData( )

	Dim fp

	Set fp = FsReadOpen( Server.MapPath("Data.txt") )
	OutData = Replace( fp.ReadAll(), vbCrLf, "<br>" )
	Call FsClose( fp )

End Function

' **********************************************************
' VIEW の編集
' **********************************************************
Function EditDataHead( )


End Function

' **********************************************************
' VIEW2 の編集
' **********************************************************
Function EditDataBody( )


End Function

%>

view2.inc


<SCRIPT language=VBScript>

' **********************************************************
' フォームのチェック
' **********************************************************
function frmMain_onSubmit()

	frmMain_onSubmit = true

end function

</SCRIPT>

<HTML>
<HEAD>
	<META http-equiv="Content-type" content="text/html; charset=Shift_JIS">
	<TITLE>ASP 雛形</TITLE>
<STYLE>
	.MyHead {
		background-color:silver
	}
	.MyCell {
		background-color:white
	}
</STYLE>
</HEAD>

<!-- *******************************************************
 ドキュメント
******************************************************** -->
<BODY>
<SPAN style='color:blue'><%= ErrMessage %></SPAN>
<SPAN style='color:black;font-weight:bold'><%= Message %></SPAN>

<!-- *******************************************************
 フォーム
******************************************************** -->
<FORM
	name=frmMain
	method=GET
	action=control.php
>

<!-- *******************************************************
 画面定義
******************************************************** -->
<TABLE border=0 bgcolor=black cellspacing=1 cellpadding=5
	width=100%
>
<TH class=MyHead>内容</TH>
<TR>
<TD class=MyCell><%= OutData %></TD>
</TR>
</TABLE>

<!-- *******************************************************
 画面番号
******************************************************** -->
<INPUT type=hidden name=GNO value="<%= PASS_BODY %>">

<!-- *******************************************************
 HEAD 部の入力データ引継ぎ用の埋め込み
******************************************************** -->
<%= InData %>
</FORM>

</BODY>
</HTML>

view.inc


<SCRIPT language=JavaScript>

// *********************************************************
// フォームのチェック
// *********************************************************
function CheckData() {

	return true;
}

</SCRIPT>


<HTML>
<HEAD>
	<META http-equiv="Content-type" content="text/html; charset=Shift_JIS">
	<TITLE>ASP 雛形</TITLE>
<STYLE>
	.MyCell {
		background-color:silver
	}
</STYLE>
</HEAD>
<BODY>

<FORM
	name=frmMain
	method=GET
	action=control.asp
	target=BodyFrame
	onSubmit='return CheckData()'
>
<TABLE border=0 bgcolor=black cellspacing=1 cellpadding=5>
<TR>
	<TD class=MyCell>
		<TEXTAREA cols=80 rows=10 name=In1Text></TEXTAREA>
	</TD>
	<TD class=MyCell>
		<INPUT type=submit name=send value="書き込み">
	</TD>
	<TD class=MyCell>
		<INPUT type=submit name=send value="読み込み">
	</TD>
	<TD class=MyCell>
		<INPUT 
			type=button
			value="Cancel"
			onClick='top.location="frame.htm"'
		>
	</TD>
</TR>
</TABLE>

<INPUT type=hidden name=GNO value="<%= PASS_COND %>">
</FORM>

</BODY>
</HTML>
>

viewmessage.inc


<HTML>
<HEAD>
	<META http-equiv="Content-type" content="text/html; charset=Shift_JIS">
	<TITLE>メッセージ表示専用</TITLE>
<STYLE>
	.MyCell {
		background-color:silver
	}
</STYLE>
</HEAD>
<BODY>
<SPAN style='color:blue'><%= ErrMessage %></SPAN>
<SPAN style='color:black;font-weight:bold'><%= Message %></SPAN>
</BODY>
</HTML>